Initial commit

2026-03-31 13:28:42 +02:00
commit 94bbdca745
224 changed files with 83161 additions and 0 deletions
--- a/darknet-master/cmake/Modules/FindCUDNN.cmake
+++ b/darknet-master/cmake/Modules/FindCUDNN.cmake
@@ -0,0 +1,104 @@
+# Distributed under the OSI-approved BSD 3-Clause License.
+# Copyright Stefano Sinigardi
+
+#.rst:
+# FindCUDNN
+# --------
+#
+# Result Variables
+# ^^^^^^^^^^^^^^^^
+#
+# This module will set the following variables in your project::
+#
+#  ``CUDNN_FOUND``
+#    True if CUDNN found on the local system
+#
+#  ``CUDNN_INCLUDE_DIRS``
+#    Location of CUDNN header files.
+#
+#  ``CUDNN_LIBRARIES``
+#    The CUDNN libraries.
+#
+#  ``CuDNN::CuDNN``
+#    The CUDNN target
+#
+
+include(FindPackageHandleStandardArgs)
+
+find_path(CUDNN_INCLUDE_DIR NAMES cudnn.h cudnn_v8.h cudnn_v7.h
+  HINTS $ENV{CUDA_PATH} $ENV{CUDA_TOOLKIT_ROOT_DIR} $ENV{CUDA_HOME} $ENV{CUDNN_ROOT_DIR} /usr/include
+  PATH_SUFFIXES cuda/include include)
+find_library(CUDNN_LIBRARY NAMES cudnn cudnn8 cudnn7
+  HINTS $ENV{CUDA_PATH} $ENV{CUDA_TOOLKIT_ROOT_DIR} $ENV{CUDA_HOME} $ENV{CUDNN_ROOT_DIR} /usr/lib/x86_64-linux-gnu/
+  PATH_SUFFIXES lib lib64 cuda/lib cuda/lib64 lib/x64 cuda/lib/x64)
+if(EXISTS "${CUDNN_INCLUDE_DIR}/cudnn.h")
+  file(READ ${CUDNN_INCLUDE_DIR}/cudnn.h CUDNN_HEADER_CONTENTS)
+elseif(EXISTS "${CUDNN_INCLUDE_DIR}/cudnn_v8.h")
+  file(READ ${CUDNN_INCLUDE_DIR}/cudnn_v8.h CUDNN_HEADER_CONTENTS)
+elseif(EXISTS "${CUDNN_INCLUDE_DIR}/cudnn_v7.h")
+  file(READ ${CUDNN_INCLUDE_DIR}/cudnn_v7.h CUDNN_HEADER_CONTENTS)
+endif()
+if(EXISTS "${CUDNN_INCLUDE_DIR}/cudnn_version.h")
+  file(READ "${CUDNN_INCLUDE_DIR}/cudnn_version.h" CUDNN_VERSION_H_CONTENTS)
+  string(APPEND CUDNN_HEADER_CONTENTS "${CUDNN_VERSION_H_CONTENTS}")
+  unset(CUDNN_VERSION_H_CONTENTS)
+elseif(EXISTS "${CUDNN_INCLUDE_DIR}/cudnn_version_v8.h")
+  file(READ "${CUDNN_INCLUDE_DIR}/cudnn_version_v8.h" CUDNN_VERSION_H_CONTENTS)
+  string(APPEND CUDNN_HEADER_CONTENTS "${CUDNN_VERSION_H_CONTENTS}")
+  unset(CUDNN_VERSION_H_CONTENTS)
+elseif(EXISTS "${CUDNN_INCLUDE_DIR}/cudnn_version_v7.h")
+  file(READ "${CUDNN_INCLUDE_DIR}/cudnn_version_v7.h" CUDNN_VERSION_H_CONTENTS)
+  string(APPEND CUDNN_HEADER_CONTENTS "${CUDNN_VERSION_H_CONTENTS}")
+  unset(CUDNN_VERSION_H_CONTENTS)
+endif()
+if(CUDNN_HEADER_CONTENTS)
+  string(REGEX MATCH "define CUDNN_MAJOR * +([0-9]+)"
+               _CUDNN_VERSION_MAJOR "${CUDNN_HEADER_CONTENTS}")
+  string(REGEX REPLACE "define CUDNN_MAJOR * +([0-9]+)" "\\1"
+               _CUDNN_VERSION_MAJOR "${_CUDNN_VERSION_MAJOR}")
+  string(REGEX MATCH "define CUDNN_MINOR * +([0-9]+)"
+               _CUDNN_VERSION_MINOR "${CUDNN_HEADER_CONTENTS}")
+  string(REGEX REPLACE "define CUDNN_MINOR * +([0-9]+)" "\\1"
+               _CUDNN_VERSION_MINOR "${_CUDNN_VERSION_MINOR}")
+  string(REGEX MATCH "define CUDNN_PATCHLEVEL * +([0-9]+)"
+               _CUDNN_VERSION_PATCH "${CUDNN_HEADER_CONTENTS}")
+  string(REGEX REPLACE "define CUDNN_PATCHLEVEL * +([0-9]+)" "\\1"
+               _CUDNN_VERSION_PATCH "${_CUDNN_VERSION_PATCH}")
+  if(NOT _CUDNN_VERSION_MAJOR)
+    set(CUDNN_VERSION "?")
+  else()
+    set(CUDNN_VERSION "${_CUDNN_VERSION_MAJOR}.${_CUDNN_VERSION_MINOR}.${_CUDNN_VERSION_PATCH}")
+  endif()
+endif()
+
+set(CUDNN_INCLUDE_DIRS ${CUDNN_INCLUDE_DIR})
+set(CUDNN_LIBRARIES ${CUDNN_LIBRARY})
+mark_as_advanced(CUDNN_LIBRARY CUDNN_INCLUDE_DIR)
+
+find_package_handle_standard_args(CUDNN
+      REQUIRED_VARS  CUDNN_INCLUDE_DIR CUDNN_LIBRARY
+      VERSION_VAR    CUDNN_VERSION
+)
+
+if(WIN32)
+  set(CUDNN_DLL_DIR ${CUDNN_INCLUDE_DIR})
+  list(TRANSFORM CUDNN_DLL_DIR APPEND "/../bin")
+  find_file(CUDNN_LIBRARY_DLL NAMES cudnn64_${CUDNN_VERSION_MAJOR}.dll PATHS ${CUDNN_DLL_DIR})
+endif()
+
+if( CUDNN_FOUND AND NOT TARGET CuDNN::CuDNN )
+  if( EXISTS "${CUDNN_LIBRARY_DLL}" )
+    add_library( CuDNN::CuDNN      SHARED IMPORTED )
+    set_target_properties( CuDNN::CuDNN PROPERTIES
+      IMPORTED_LOCATION                 "${CUDNN_LIBRARY_DLL}"
+      IMPORTED_IMPLIB                   "${CUDNN_LIBRARY}"
+      INTERFACE_INCLUDE_DIRECTORIES     "${CUDNN_INCLUDE_DIR}"
+      IMPORTED_LINK_INTERFACE_LANGUAGES "C" )
+  else()
+    add_library( CuDNN::CuDNN      UNKNOWN IMPORTED )
+    set_target_properties( CuDNN::CuDNN PROPERTIES
+      IMPORTED_LOCATION                 "${CUDNN_LIBRARY}"
+      INTERFACE_INCLUDE_DIRECTORIES     "${CUDNN_INCLUDE_DIR}"
+      IMPORTED_LINK_INTERFACE_LANGUAGES "C" )
+  endif()
+endif()
--- a/darknet-master/cmake/Modules/FindPThreads4W.cmake
+++ b/darknet-master/cmake/Modules/FindPThreads4W.cmake
@@ -0,0 +1,79 @@
+# Distributed under the OSI-approved BSD 3-Clause License.
+# Copyright Stefano Sinigardi
+
+#.rst:
+# FindPThreads4W
+# ------------
+#
+# Find the PThread4W includes and library.
+#
+# Result Variables
+# ^^^^^^^^^^^^^^^^
+#
+# This script defines the following variables:
+#
+# ``PThreads4W_FOUND``
+#   True if PThreads4W library found
+#
+# ``PThreads4W_VERSION``
+#   Containing the PThreads4W version tag (manually defined)
+#
+# ``PThreads4W_INCLUDE_DIR``
+#   Location of PThreads4W headers
+#
+# ``PThreads4W_LIBRARY``
+#   List of libraries to link with when using PThreads4W (no exception handling)
+#
+# Result Targets
+# ^^^^^^^^^^^^^^^^
+#
+# This script defines the following targets:
+#
+# ``PThreads4W::PThreads4W``
+#   Target to use PThreads4W (no exception handling)
+#
+
+include(${CMAKE_ROOT}/Modules/FindPackageHandleStandardArgs.cmake)
+include(${CMAKE_ROOT}/Modules/SelectLibraryConfigurations.cmake)
+
+if(NOT PThreads4W_INCLUDE_DIR)
+  find_path(PThreads4W_INCLUDE_DIR NAMES pthread.h)
+endif()
+
+set(PThreads4W_MAJOR_VERSION 2)
+set(PThreads4W_MINOR_VERSION 0)
+set(PThreads4W_PATCH_VERSION 0)
+set(PThreads4W_VERSION "${PThreads4W_MAJOR_VERSION}.${PThreads4W_MINOR_VERSION}.${PThreads4W_PATCH_VERSION}")
+
+# Allow libraries to be set manually
+if(NOT PThreads4W_LIBRARY)
+  find_library(PThreads4W_LIBRARY NAMES pthreadVC${PThreads4W_MAJOR_VERSION})
+endif()
+
+find_package_handle_standard_args(PThreads4W DEFAULT_MSG PThreads4W_LIBRARY PThreads4W_INCLUDE_DIR)
+mark_as_advanced(PThreads4W_INCLUDE_DIR PThreads4W_LIBRARY )
+
+set(PThreads4W_DLL_DIR ${PThreads4W_INCLUDE_DIR})
+list(TRANSFORM PThreads4W_DLL_DIR APPEND "/../bin")
+message(STATUS "PThreads4W_DLL_DIR: ${PThreads4W_DLL_DIR}")
+
+find_file(PThreads4W_LIBRARY_DLL NAMES pthreadVC${PThreads4W_MAJOR_VERSION}.dll PATHS ${PThreads4W_DLL_DIR})
+
+if( PThreads4W_FOUND AND NOT TARGET PThreads4W::PThreads4W )
+  if( EXISTS "${PThreads4W_LIBRARY_RELEASE_DLL}" )
+    add_library( PThreads4W::PThreads4W      SHARED IMPORTED )
+    set_target_properties( PThreads4W::PThreads4W PROPERTIES
+      IMPORTED_LOCATION_RELEASE         "${PThreads4W_LIBRARY_DLL}"
+      IMPORTED_IMPLIB                   "${PThreads4W_LIBRARY}"
+      INTERFACE_INCLUDE_DIRECTORIES     "${PThreads4W_INCLUDE_DIR}"
+      IMPORTED_CONFIGURATIONS           Release
+      IMPORTED_LINK_INTERFACE_LANGUAGES "C" )
+  else()
+    add_library( PThreads4W::PThreads4W      UNKNOWN IMPORTED )
+    set_target_properties( PThreads4W::PThreads4W PROPERTIES
+      IMPORTED_LOCATION_RELEASE         "${PThreads4W_LIBRARY}"
+      INTERFACE_INCLUDE_DIRECTORIES     "${PThreads4W_INCLUDE_DIR}"
+      IMPORTED_CONFIGURATIONS           Release
+      IMPORTED_LINK_INTERFACE_LANGUAGES "C" )
+  endif()
+endif()
--- a/darknet-master/cmake/Modules/FindStb.cmake
+++ b/darknet-master/cmake/Modules/FindStb.cmake
@@ -0,0 +1,30 @@
+# Distributed under the OSI-approved BSD 3-Clause License.
+# Copyright Stefano Sinigardi
+
+#.rst:
+# FindStb
+# ------------
+#
+# Find the Stb include headers.
+#
+# Result Variables
+# ^^^^^^^^^^^^^^^^
+#
+# This module defines the following variables:
+#
+# ``Stb_FOUND``
+#   True if Stb library found
+#
+# ``Stb_INCLUDE_DIR``
+#   Location of Stb headers
+#
+
+include(${CMAKE_ROOT}/Modules/FindPackageHandleStandardArgs.cmake)
+include(${CMAKE_ROOT}/Modules/SelectLibraryConfigurations.cmake)
+
+if(NOT Stb_INCLUDE_DIR)
+  find_path(Stb_INCLUDE_DIR NAMES stb_image.h PATHS ${Stb_DIR} PATH_SUFFIXES include)
+endif()
+
+find_package_handle_standard_args(Stb DEFAULT_MSG Stb_INCLUDE_DIR)
+mark_as_advanced(Stb_INCLUDE_DIR)